搜索
由繁至简的炒股秘籍股票配资送值得信赖我出资你炒股赚大钱自己操盘配资财源滚滚
查看: 4474|回复: 2

yngs的原著[公式的解读与优化]

 关闭 [复制链接]
发表于 2003-8-19 06:27 | 显示全部楼层

yngs的原著[公式的解读与优化]

来自:MACD论坛(bbs.macd.cn) 作者:女将 浏览:4474 回复:2

马上注册,结交更多好友,享用更多功能,让你轻松玩转社区。

您需要 登录 才可以下载或查看,没有帐号?立即注册

x
公式的解读与优化

首先衷心地感谢公式的原作者,从你们的公式里我得到了很多...。这里进行的解读是与朋友们的一种交流,真诚的希望你们给予帮助和斧正。
      交流中获得的分析家公式我们一般先进行破解和解读搞清楚公式的编制思路,同时解除其时间限制,如果公式有参考价值就进一步进行整理、测试、优化。

目录:
1、A行情发展
2、Q起死回生
3、决策1号

A行情发展
经过破解并去除时间限制后得到原码如下:
{n:10,1000,138}
Var3:=LLV(HIGH,240);
Var4:=100*(CLOSE-Var3)/Var3;
Var5:=REF(LLV(CLOSE,480),1);
Var6:=REF(HHV(CLOSE,480),1);
Var7:=100*(CLOSE-Var5)/(Var6-Var5);
Var8:=(CLOSE-LLV(CLOSE,2000))/(HHV(CLOSE,2000)-LLV(CLOSE,2500))*100;
Var9:=(CLOSE-LLV(LOW,1200))/(HHV(HIGH,1200)-LLV(LOW,1200))*100;
VarA:=(CLOSE-LLV(CLOSE,140))/(HHV(CLOSE,140)-LLV(CLOSE,140))*100;
VarB:=(CLOSE-LLV(LOW,570))/(HHV(HIGH,570)-LLV(LOW,570))*100;
VarC:=(HIGH+LOW+CLOSE)/3;
VarD:=(VarC-MA(VarC,72))/(0.015*AVEDEV(VarC,72));
VarE:=EMA(100*(CLOSE-LLV(LOW,100))/(HHV(HIGH,100)-LLV(LOW,100)),7);
VarF:=(CLOSE-LLV(LOW,250))/(HHV(HIGH,250)-LLV(LOW,250))*100;
Var10:=SMA(VarF,72,1);
Var11:=SMA(Var10,34,1);
Var12:=3*Var10-2*Var11;
Var13:=(CLOSE-LLV(LOW,125))/(HHV(HIGH,125)-LLV(LOW,125))*100;
Var14:=SMA(Var13,34,1);
Var15:=SMA(Var14,26,1);
Var16:=3*Var14-2*Var15;
短线行情: Var16, , COLOR6699ff;
长线行情: Var12, , COLORGREEN;
底部反弹: IF(FILTER(CROSS(短线行情,0) AND VarE<13,5)=1,50,0), , COLORWHITE;
Var17:=(CLOSE-LLV(CLOSE,n))/(HHV(CLOSE,N)-LLV(CLOSE,N))*100;
Var18:=IF(FILTER(长线行情<0,6)=1,1,0);
Var19:=IF(FILTER(Var17=0,5)=1,1,0);
短线介入点: IF(FILTER(CROSS(短线行情,长线行情) AND VarE<15 AND (短线行情<5 OR 短线行情<22),250)=1,50,0), , COLORMAGENTA;
长线介入点: IF(FILTER(CROSS(长线行情,0),5)=1,80,0), , COLORYELLOW;
Var1A:=CROSS(短线行情,长线行情) AND 短线行情<13;
DRAWTEXT(底部反弹>0,49,'☆'), ,  COLORRED;
DRAWTEXT(短线介入点>0,50,'★'), ,  COLORRED;
DRAWTEXT(CROSS(短线行情,长线行情) AND 短线行情<13 AND 短线行情>0,CROSS(短线行情,长线行情),'●'), , COLORMAGENTA;
DRAWTEXT(Var1A>0,25,'强势跟班获利了结!!'), , COLORRED;
STICKLINE(Var19 AND Var18>0,0,50,1,0), , COLORYELLOW;
STICKLINE(短线行情<0,0,-5,1,0), , COLORRED;
STICKLINE(短线行情>100,100,110,1,0), , COLORff0066;
DRAWTEXT(长线介入点>0,80,'长线介入点'),COLORYELLOW;


{Var3:=LLV(HIGH,240);
Var4:=100*(CLOSE-Var3)/Var3;
Var5:=REF(LLV(CLOSE,480),1);
Var6:=REF(HHV(CLOSE,480),1);
Var7:=100*(CLOSE-Var5)/(Var6-Var5);
Var8:=(CLOSE-LLV(CLOSE,2000))/(HHV(CLOSE,2000)-LLV(CLOSE,2500))*100;
Var9:=(CLOSE-LLV(LOW,1200))/(HHV(HIGH,1200)-LLV(LOW,1200))*100;
VarA:=(CLOSE-LLV(CLOSE,140))/(HHV(CLOSE,140)-LLV(CLOSE,140))*100;
VarB:=(CLOSE-LLV(LOW,570))/(HHV(HIGH,570)-LLV(LOW,570))*100;
VarC:=(HIGH+LOW+CLOSE)/3;
VarD:=(VarC-MA(VarC,72))/(0.015*AVEDEV(VarC,72));}
这一段主要是超长周期的威廉指标,周期太长对今后的股价运行已没有任何意义,公式的表达式也没有调用,删除。

{VarE:=EMA(100*(CLOSE-LLV(LOW,100))/(HHV(HIGH,100)-LLV(LOW,100)),7);}
这是参数为100的K值。

{VarF:=(CLOSE-LLV(LOW,250))/(HHV(HIGH,250)-LLV(LOW,250))*100;
Var10:=SMA(VarF,72,1);
Var11:=SMA(Var10,34,1);
Var12:=3*Var10-2*Var11;}
周期参数为250的KDJ指标。

{Var13:=(CLOSE-LLV(LOW,125))/(HHV(HIGH,125)-LLV(LOW,125))*100;
Var14:=SMA(Var13,34,1);
Var15:=SMA(Var14,26,1);
Var16:=3*Var14-2*Var15;}
周期参数为125的KDJ指标。

由此可以看出这个公式是不同(长短)周期的KDJ的变形组合。因为它的周期都在100以上属长线指标,所谓“短线行情”并不短,对实盘操做意义不大,所以把上面KDJ的周期参数改短些,整理如下:
{Var1:=EMA(100*(CLOSE-LLV(LOW,89))/(HHV(HIGH,89)-LLV(LOW,89)),7);
Var2:=(CLOSE-LLV(LOW,125))/(HHV(HIGH,125)-LLV(LOW,125))*100;
Var3:=SMA(Var2,72,1);
Var4:=SMA(Var3,34,1);
Var5:=3*Var3-2*Var4;
Var6:=(CLOSE-LLV(LOW,34))/(HHV(HIGH,34)-LLV(LOW,34))*100;
Var7:=SMA(Var6,8,1);
Var8:=SMA(Var7,5,1);
Var9:=3*Var7-2*Var8;
短线行情: Var9, , COLOR6699ff;
长线行情: Var5, , COLORGREEN;}

{底部反弹: IF(FILTER(CROSS(短线行情,0) AND VarE<13,5)=1,50,0), , COLORWHITE;}由于前面调整(缩短)了周期此句亦做相应调整:
{底部反弹: IF(FILTER(CROSS(短线行情,5) AND Var5<5 and var1<5,5)=1,50,0), , COLORWHITE;}
这样出击点大幅增加,具有了实战参考作用。

{短线介入点: IF(FILTER(CROSS(短线行情,长线行情) AND VarE<15 AND (短线行情<5 OR 短线行情<22),250)=1,50,0), , COLORMAGENTA;}
{短线行情<5 }这个条件纯属多余,过滤周期长达一年(250天)这样的“短线”只应天上有,我把它整理成:
{短线介入点: IF(FILTER((CROSS(短线行情,长线行情) or CROSS(短线行情,var1) and var1<var5) and var1<10 and var5<13,5)=1,50,0), , COLORMAGENTA;}
5天,呵呵...咱们还是回到人间吧!

长线介入点我改了改:
{长线介入点: IF(FILTER(长线行情<0 and var9<13,5)=1,80,0), , COLORYELLOW;}
大家可以对照看比原来好了许多。

{Var17:=(CLOSE-LLV(CLOSE,n))/(HHV(CLOSE,N)-LLV(CLOSE,N))*100;
Var18:=IF(FILTER(长线行情<0,6)=1,1,0);
Var19:=IF(FILTER(Var17=0,5)=1,1,0);}和
{STICKLINE(Var19 AND Var18>0,0,50,1,0), , COLORYELLOW;}
表示周期分别为100和250的两条指标线小于等于0时画一条高50的黄柱线,出击率极低,而且上面的长线介入点已经将其包含,删除。

{Var1A:=CROSS(短线行情,长线行情) AND 短线行情<13;
DRAWTEXT(Var1A>0,25,'强势跟班获利了结!!'), , COLORRED;}
这两句是说抄底抢反弹见好就收。

{DRAWTEXT(底部反弹>0,49,'☆'), ,  COLORRED;
DRAWTEXT(短线介入点>0,50,'★'), ,  COLORRED;
DRAWTEXT(CROSS(短线行情,长线行情) AND 短线行情<13 AND 短线行情>0,CROSS(短线行情,长线行情),'●'), , COLORMAGENTA;
STICKLINE(短线行情<0,0,-5,1,0), , COLORRED;
STICKLINE(短线行情>100,100,110,1,0), , COLORff0066;
DRAWTEXT(长线介入点>0,80,'长线介入点'),COLORYELLOW; }
剩余的这部分是辅助表示,保留就可以了。



最终的表达式为:
Var1:=EMA(100*(CLOSE-LLV(LOW,89))/(HHV(HIGH,89)-LLV(LOW,89)),7);
Var2:=(CLOSE-LLV(LOW,125))/(HHV(HIGH,125)-LLV(LOW,125))*100;
Var3:=SMA(Var2,72,1);
Var4:=SMA(Var3,34,1);
Var5:=3*Var3-2*Var4;
Var6:=(CLOSE-LLV(LOW,34))/(HHV(HIGH,34)-LLV(LOW,34))*100;
Var7:=SMA(Var6,8,1);
Var8:=SMA(Var7,5,1);
Var9:=3*Var7-2*Var8;
短线行情: Var9, , COLOR6699ff;
长线行情: Var5, , COLORGREEN;
底部反弹: IF(FILTER(CROSS(短线行情,5) AND Var5<5 and var1<5,5)=1,50,0), , COLORWHITE;
短线介入点: IF(FILTER((CROSS(短线行情,长线行情) or CROSS(短线行情,var1) and var1<var5) and var1<10 and var5<20,5)=1,50,0), , COLORMAGENTA;
长线介入点: IF(FILTER(长线行情<0 and var9<13,5)=1,80,0), , COLORYELLOW;
Var1A:=CROSS(短线行情,长线行情) AND 短线行情<13;
DRAWTEXT(底部反弹>0,49,'☆'), ,  COLORRED;
DRAWTEXT(短线介入点>0,50,'★'), ,  COLORRED;
DRAWTEXT(CROSS(短线行情,长线行情) AND 短线行情<13 AND 短线行情>0,CROSS(短线行情,长线行情),'●'), , COLORMAGENTA;
DRAWTEXT(Var1A>0,25,'强势跟班获利了结!!'), , COLORRED;
STICKLINE(短线行情<0,0,-5,1,0), , COLORRED;
STICKLINE(短线行情>100,100,110,1,0), , COLORff0066;
DRAWTEXT(长线介入点>0,80,'长线介入点'),COLORYELLOW;
感觉上短线介入点还不够满意,希望大家继续优化。
!本公式适用于下降通道的股票!



使用说明:
(A行情发展):
“短线行情”线底部上穿“长线行情”线为强势,
“短线行情”线顶部下穿“长线行情”线为下跌,
短线行情跌落至0以下为底部,大与80以上为风险区。

注:本指标可预测一只股票的未来行情与发展趋势,是短线获利必不可少的重要指标,是长线不可缺乏利器。

红色为安全区,即底部买进信号;
蓝色为风险区,即顶部卖出信号;
红色安全区与蓝色风险区之间,即是短线波段操作的好帮手。
底部反弹=50,即是红色底部消失即将上涨;
短线介入点=50;在5--15--30--60--日线操作都较为合适。
长线介入点=80,在日线操作较为合适。
做短线看“短线行情”;
做长线看“长线行情”;



Q起死回生
经配色后的原码
Var1:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
民富: SMA(Var1,3,1);
D: SMA(民富,3,1);
江油小马电脑: IF(D<20 AND CROSS(民富,D),50,0), , COLORMAGENTA;
起死回生: IF(BARSLAST(江油小马电脑=50)<=9 AND BARSLAST(江油小马电脑=50)>5 AND CROSS(D,民富) AND D<70,68,5), , COLORRED;

这是一个典型的随机选股指标,表达式带有广告色彩
{Var1:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
民富: SMA(Var1,3,1);
D: SMA(民富,3,1);}连参数都没有变的标准随机指标,还原后成
{Var1:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K: SMA(Var1,3,1);
D: SMA(K,3,1);}

{江油小马电脑: IF(D<20 AND CROSS(民富,D),50,0), , COLORMAGENTA;}
表示KD低位金叉,整理为
{低位金叉:if(D<20 AND CROSS(k,D),40,0)COLORMAGENTA;}

{起死回生: IF(BARSLAST(江油小马电脑=50)<=9 AND BARSLAST(江油小马电脑=50)>5 AND CROSS(D,民富) AND D<70,68,5), , COLORRED;}表示在KD低位金叉后的5-9个周期内KD中低位死叉。这一句的思路非常有意义!一般选股都是金叉或二次金叉,而它却是选金叉后的死叉买入,常常领先一步,足见公式作者对随机指标的研究颇深,也是我公开解读该公式的原因。我对条件参数做了点修改,尽量避免出击点在高位。
{起死回生:if(BARSLAST(低位金叉)<=9 AND BARSLAST(低位金叉)>2  AND CROSS(D,k) AND D<30,60,0) , COLORRED;}



最终的原码为:
Var1:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
k:SMA(Var1,3,1);
D:SMA(k,3,1);
低位金叉:if(D<20 AND CROSS(k,D),40,0)COLORMAGENTA;
起死回生:if(BARSLAST(低位金叉)<=9 AND BARSLAST(低位金叉)>2  AND CROSS(D,k) AND D<30,60,0) , COLORRED;

操作说明
顾名思义,对图操作即可。为避免不必要的损失,建议对刚刚大幅炒作过的个股留一份戒心。



决策1号
公式原码
{m=3;n=4}
MF: CLOSE-REF(CLOSE,2);
Var1:=MF>MIN(REF(MF,1),REF(MF,2));
Var2:=REF(MF,2)>MF AND REF(MF,1)>MF;
Var3:=REF(CLOSE,1)+MIN(MF,REF(MF,1));
Var4:=REF(CLOSE,1)+MAX(MF,REF(MF,1));
Var5:=ZIG(N,M1);
Var6:=REF(Var5,2)>REF(Var5,1) AND Var5>REF(Var5,1);
Var7:=REF(Var5,2)<REF(Var5,1) AND Var5<REF(Var5,1);
多头买入: Var1 AND CLOSE>Var3 AND Var6, LINESTICK;
空头信号: Var2 AND CLOSE<Var4 AND Var7, CIRCLEDOT;
G: 1, POINTDOT;
D: -1, POINTDOT;

用法注释:
ZJB决策1号)  
    采用欧美经记人操盘交易程式,再辅以“股价波幅因子”“速量因子MF”编程得出。经电脑测试是一种客观的慨率胜算,
如配以“战无不胜”能保证你在十次交易中,有七八次赢利!
1)进场时机以"MF"决定,出场时机以了结点决定。
2)依自己操盘特点决定参数大小。

{MF: CLOSE-REF(CLOSE,2);}“速量因子MF”。

{Var1:=MF>MIN(REF(MF,1),REF(MF,2));
Var2:=REF(MF,2)>MF AND REF(MF,1)>MF;}定义了速量因子MF的两个相对位置。

{Var3:=REF(CLOSE,1)+MIN(MF,REF(MF,1));
Var4:=REF(CLOSE,1)+MAX(MF,REF(MF,1));}昨天收盘价分别加上速量因子MF的大小相关系数。

{Var5:=ZIG(N,M1);}“股价波幅因子”。

{Var6:=REF(Var5,2)>REF(Var5,1) AND Var5>REF(Var5,1);
Var7:=REF(Var5,2)<REF(Var5,1) AND Var5<REF(Var5,1);}定义了股价波幅因子的两个相对位置。

{多头买入: Var1 AND CLOSE>Var3 AND Var6, LINESTICK;
空头信号: Var2 AND CLOSE<Var4 AND Var7, CIRCLEDOT;}定义买卖条件。

{G: 1, POINTDOT;
D: -1, POINTDOT;}顶底线。
   
    由上解读可知公式思路清晰、定义准确,但是其股价波幅因子使用了未来函数ZIG,应朋友要求对它进行优化为无未来数据的公式:
1、把与ZIG函数有关的所有内容删除;
2、调整速量因子MF的参数{MF: CLOSE-REF(CLOSE,12);};
3、增加一条速量因子MF的平滑移动平均线{mf1:=ema( CLOSE-REF(CLOSE,10),5);};
4、定义买卖条件{多头买入: Var1 AND CLOSE>Var3 AND CROSS(mf,mf1) and mf1<-0.65, LINESTICK;
空头信号: Var2 AND CLOSE<Var4 AND CROSS(mf1,mf) and mf1>0.382, CIRCLEDOT;};
5、原顶底线已无意义删除。



最终的原码为:
MF: CLOSE-REF(CLOSE,12);
mf1:=ema( CLOSE-REF(CLOSE,10),5);
Var1:=MF>MIN(REF(MF,1),REF(MF,2));
Var2:=REF(MF,2)>MF AND REF(MF,1)>MF;
Var3:=REF(CLOSE,1)+MIN(MF,REF(MF,1));
Var4:=REF(CLOSE,1)+MAX(MF,REF(MF,1));
多头买入: Var1 AND CLOSE>Var3 AND CROSS(mf,mf1) and mf1<-0.65, LINESTICK;
空头信号: Var2 AND CLOSE<Var4 AND CROSS(mf1,mf) and mf1>0.382, CIRCLEDOT;

注:本优化主要是针对去除未来函数进行是一种思路,买入信号还可以进一步优化。
金币:
奖励:
热心:
注册时间:
2003-5-2

回复 使用道具 举报

发表于 2003-8-19 10:43 | 显示全部楼层
谢谢女将花费如此心血为公式爱好者提供了丰盛大餐,精品贴+10分。
金币:
奖励:
热心:
注册时间:
2001-10-31

回复 使用道具 举报

发表于 2003-8-19 10:46 | 显示全部楼层
看了一下,虽然信号不错,但是终究是别人的公式,自己搞不懂他的理念,还是不能用。另,第二个公式有些错误,我大概修改了一下:
MF: CLOSE-REF(CLOSE,2);
Var1:=MF>MIN(REF(MF,1),REF(MF,2));
Var2:=REF(MF,2)>MF AND REF(MF,1)>MF;
Var3:=REF(CLOSE,1)+MIN(MF,REF(MF,1));
Var4:=REF(CLOSE,1)+MAX(MF,REF(MF,1));
Var5:=ZIG(3,M);
Var6:=REF(Var5,2)>REF(Var5,1) AND Var5>REF(Var5,1);
Var7:=REF(Var5,2)<REF(Var5,1) AND Var5<REF(Var5,1);
多头买入: Var1 AND CLOSE>Var3 AND Var6, LINESTICK;
空头信号: Var2 AND CLOSE<Var4 AND Var7, CIRCLEDOT;
G: 1, POINTDOT;
D: -1, POINTDOT;

是其中ZIG的语句错误。
金币:
奖励:
热心:
注册时间:
2001-12-4

回复 使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

本站声明:1、本站所有广告均与MACD无关;2、MACD仅提供交流平台,网友发布信息非MACD观点与意思表达,因网友发布的信息造成任何后果,均与MACD无关。
MACD俱乐部(1997-2019)官方域名:macd.cn   MACD网校(2006-2019)官方域名:macdwx.com
值班热线[9:00—17:30]:18292674919   24小时网站应急电话:18292674919
找回密码、投诉QQ:89918815 友情链接QQ:95008905 广告商务联系QQ:17017506 电话:18292674919
增值电信业务经营许可证: 陕ICP19026207号—2  陕ICP备20004035号

举报|意见反馈|Archiver|手机版|小黑屋|MACD俱乐部 ( 陕ICP备20004035号 )

GMT+8, 2024-3-28 17:26 , Processed in 0.060926 second(s), 8 queries , Redis On.

Powered by Discuz! X3.4

© 2001-2017 Comsenz Inc.

快速回复 返回顶部 返回列表