通达信 缠论笔公式

梦忠溪

通达信 缠论笔公式

来自：MACD论坛(bbs.macd.cn) 作者：梦忠溪 浏览：3470 回复：7

有没有谁可以提供通达信 缠论笔公式

yinlong5229

没有听说过。都是自己画的

梦忠溪

有没有牛人有这种指标代码？

通行证1

无相无辩

当然可以有，因为牛人太多！
转一位分笔代码：

{一、标记所有顶分型及底分型的顶部或底部，以下简称“节点”。};
{11、非包含关系的分型端点预选};


顶价:=REF(H,BARSLAST(H>REF(H,1)));
底价:=REF(L,BARSLAST(L<REF(L,1)));

分型顶0:=H>REF(顶价,1) AND L>REF(底价,1);
分型底0:=L<REF(底价,1) AND H<REF(顶价,1);

分型顶1:=分型顶0 AND H=HHV(H,BARSLAST(分型底0));
分型底1:=分型底0 AND L=LLV(L,BARSLAST(分型顶0));

分型顶:=FILTERX(分型顶1,BARSLAST(分型底1));
分型底:=FILTERX(分型底1,BARSLAST(分型顶1));

{二、对符合形成笔条件的分型节点进行粗选。};
{注：符合笔条件的分型应符合缠论以下条件：
     1、力度：本笔的起点与终点之间，必须存在最高的低点与最低的高点分离（缠论无要求，可删除）
     2、包含：无包含关系的K线数量必须达到二根以上，即：右肩+左肩+本笔。
     3、数量：本笔所有K线数量，在无包含关系的情况下，除起点K线外，其余数量必须达到三以上，即：右肩+过渡+左肩+本笔。};
{21、以分型顶底为起点形成笔的要求，进行第一次筛选，得到笔的第一类过渡期顶、底。};
UP1:=BARSLAST(分型底);
顶力度1:=HHV(L,UP1+1)>LLV(H,UP1+1);
顶包含1:=COUNT(L>REF(L,1),UP1)>2 AND COUNT(H>REF(H,1),UP1)>2;

DN1:=BARSLAST(分型顶);
底力度1:=HHV(L,DN1+1)>LLV(H,DN1+1);
底包含1:=COUNT(H<REF(H,1),DN1)>2 AND COUNT(L<REF(L,1),DN1)>2;

笔顶10:=分型顶 AND UP1>3 AND 顶力度1 AND 顶包含1;
笔底10:=分型底 AND DN1>3 AND 底力度1 AND 底包含1;

{211：取同一笔中的最高点或最低点为笔的分型顶、底端，并过滤};
笔顶11:=笔顶10 AND H=HHV(H,BARSLAST(笔底10));
笔底11:=笔底10 AND L=LLV(L,BARSLAST(笔顶10));

{212：针对前述顶底再次过滤同一笔中的最高点或最低点为笔的分型顶、底端，并过滤};
笔顶12:=笔顶11 AND H=HHV(H,BARSLAST(笔底11));
笔底12:=笔底11 AND L=LLV(L,BARSLAST(笔顶11));

笔顶1:=FILTERX(笔顶12,BARSLAST(笔底12));
笔底1:=FILTERX(笔底12,BARSLAST(笔顶12));


{22、以第一类过渡期顶、底分型为起点形成笔的要求，进行第二次筛选，得到笔的第二类过渡期顶、底。};
{注：对以顶底分型不成笔的节点，但对第一类过渡顶底满足笔的条件，应选入。}
UP2:=BARSLAST(笔底1);
顶力度2:=HHV(L,UP2+1)>LLV(H,UP2+1);
顶包含2:=COUNT(L>REF(L,1),UP2)>2 AND COUNT(H>REF(H,1),UP2)>2;

DN2:=BARSLAST(笔顶1);
底力度2:=HHV(L,DN2+1)>LLV(H,DN2+1);
底包含2:=COUNT(H<REF(H,1),DN2)>2 AND COUNT(L<REF(L,1),DN2)>2;

笔顶20:=分型顶 AND UP2>3 AND 顶力度2 AND 顶包含2;
笔底20:=分型底 AND DN2>3 AND 底力度2 AND 底包含2;

{221：取同一笔中的最高点或最低点为笔的分型顶、底端};
笔顶21:=笔顶20 AND H=HHV(H,BARSLAST(笔底20));
笔底21:=笔底20 AND L=LLV(L,BARSLAST(笔顶20));

笔顶2:=FILTERX(笔顶21,BARSLAST(笔底21));
笔底2:=FILTERX(笔底21,BARSLAST(笔顶21));



{三、合并第一类过渡期顶、底和第二类过渡期顶、底，作为后续分型的参考节点。};
笔顶3:=笔顶1 OR 笔顶2;
笔底3:=笔底1 OR 笔底2;



{四、前述二种过渡类顶底合并后，存在持续分型、不成笔分型，对这类非笔分型节点进行以下筛选：};
{41、第一次过滤以前述“笔顶底3”为起止点的持续性的高底点分型节点，删除非本笔最高、最低点的节点，并向前过滤。};
笔顶41:=FILTERX(笔顶3 AND H=HHV(H,BARSLAST(笔底3)),BARSLAST(笔底3));
笔底41:=FILTERX(笔底3 AND L=LLV(L,BARSLAST(笔顶3)),BARSLAST(笔顶3));


{42、第二次过滤以前述“笔顶底41”为起点的持续性的高底点分型节点，删除非本笔最高、最低点的节点，并向前过滤。};
笔顶42:=FILTERX(笔顶41 AND H=HHV(H,BARSLAST(笔底41)),BARSLAST(笔底41));
笔底42:=FILTERX(笔底41 AND L=LLV(L,BARSLAST(笔顶41)),BARSLAST(笔顶41));

{43、过滤前述以“笔顶底42”为起止点的笔，删除顶底相隔不足1日的顶底端点，取高低点，并过滤。};
笔顶431:=笔顶42 AND (BARSLAST(笔底42)>1 OR BARSLAST(笔底42)=DRAWNULL);
笔底431:=笔底42 AND (BARSLAST(笔顶42)>1 OR BARSLAST(笔顶42)=DRAWNULL);

笔顶432:=笔顶431 AND (H=HHV(H,BARSLAST(笔底431)) OR BARSLAST(笔底431)=DRAWNULL);
笔底432:=笔底431 AND (L=LLV(L,BARSLAST(笔顶431)) OR BARSLAST(笔顶431)=DRAWNULL);

笔顶43:=FILTERX(笔顶432,BARSLAST(笔底431));
笔底43:=FILTERX(笔底432,BARSLAST(笔顶431));

{44、过滤前述以“笔顶底43”为起止点的笔，删除顶底相隔不足2日的顶底端点，取高低点，并过滤。};
笔顶441:=笔顶43 AND (BARSLAST(笔底43)>2 OR BARSLAST(笔底43)=DRAWNULL);
笔底441:=笔底43 AND (BARSLAST(笔顶43)>2 OR BARSLAST(笔顶43)=DRAWNULL);

笔顶442:=笔顶441 AND (H=HHV(H,BARSLAST(笔底441)) OR BARSLAST(笔底441)=DRAWNULL);
笔底442:=笔底441 AND (L=LLV(L,BARSLAST(笔顶441)) OR BARSLAST(笔顶441)=DRAWNULL);

笔顶44:=FILTERX(笔顶442,BARSLAST(笔底441));
笔底44:=FILTERX(笔底442,BARSLAST(笔顶441));

{45、过滤前述以“笔顶底44”为起止点的笔，删除顶底相隔不足3日的顶底端点，取高低点，并过滤。};
笔顶451:=笔顶44 AND (BARSLAST(笔底44)>3 OR BARSLAST(笔底44)=DRAWNULL);
笔底451:=笔底44 AND (BARSLAST(笔顶44)>3 OR BARSLAST(笔顶44)=DRAWNULL);

笔顶452:=笔顶451 AND (H=HHV(H,BARSLAST(笔底451)) OR BARSLAST(笔底451)=DRAWNULL);
笔底452:=笔底451 AND (L=LLV(L,BARSLAST(笔顶451)) OR BARSLAST(笔顶451)=DRAWNULL);

笔顶45:=FILTERX(笔顶452,BARSLAST(笔底452));
笔底45:=FILTERX(笔底452,BARSLAST(笔顶452));


{五、前述删连续端点，将造成间隔端点符合笔条件的误删除，本段进行回补};
{51、以“笔顶底43”为笔终点(且不同为“笔顶底45”)，向起点“笔顶底45”进行判断，如果符合笔成立条件，则新增为顶底节点。}
{511、第一步加笔底，并过滤：};
DN511:=BARSLAST(笔顶45);
底力度511:=HHV(L,DN511+1)>LLV(H,DN511+1);
底包含511:=COUNT(H<REF(H,1),DN511)>2 AND COUNT(L<REF(L,1),DN511)>2;
笔底511:=笔底43 AND (笔底45<>1) AND DN511>3 AND 底力度511 AND 底包含511 AND (L=LLV(L,BARSLAST(笔顶45)));
笔底51:=FILTERX(笔底511,BARSLAST(笔顶45));

{512、第二步加笔顶，并过滤：};
UP512:=BARSLAST(笔底45);
顶力度512:=HHV(L,UP512+1)>LLV(H,UP512+1);
顶包含512:=COUNT(L>REF(L,1),UP512)>2 AND COUNT(H>REF(H,1),UP512)>2;
笔顶512:=笔顶43 AND (笔顶45<>1) AND UP512>3 AND 顶力度512 AND 顶包含512 AND (H=HHV(H,BARSLAST(笔底45)));
笔顶51:=FILTERX(笔顶512,BARSLAST(笔底45));

{52、合并回补顶底后的笔端点，并过滤};
笔顶521:=笔顶45 OR 笔顶51;
笔底521:=笔底45 OR 笔底51;

笔顶52:=FILTERX(笔顶521 AND H=HHV(H,BARSLAST(笔底521)),BARSLAST(笔底521));
笔底52:=FILTERX(笔底521 AND L=LLV(L,BARSLAST(笔顶521)),BARSLAST(笔顶521));

{53、删除回补后不成笔的端点，并过滤};
UP53:=BARSLAST(笔底52);
顶力度53:=HHV(L,UP53+1)>LLV(H,UP53+1);
顶包含53:=COUNT(L>REF(L,1),UP53)>2 AND COUNT(H>REF(H,1),UP53)>2;

DN53:=BARSLAST(笔顶52);
底力度53:=HHV(L,DN53+1)>LLV(H,DN53+1);
底包含53:=COUNT(H<REF(H,1),DN53)>2 AND COUNT(L<REF(L,1),DN53)>2;

笔顶53:=笔顶52 AND UP53>3 AND 顶力度53 AND 顶包含53 AND (H=HHV(H,BARSLAST(笔底52)));
笔底53:=笔底52 AND DN53>3 AND 底力度53 AND 底包含53 AND (L=LLV(L,BARSLAST(笔顶52)));

{54、过滤无用端点};
笔顶54:=FILTERX(笔顶53 AND H=HHV(H,BARSLAST(笔底53)),BARSLAST(笔底53));
笔底54:=FILTERX(笔底53 AND L=LLV(L,BARSLAST(笔顶53)),BARSLAST(笔顶53));

{55、最后修正顶底不在高低点处的情况，包括非笔破坏前笔高低点，造成原笔延续的情况。}
笔顶55:={分型顶 AND}
                    H=HHV(H,BARSLAST(笔底54)) AND L>LLV(L,BARSLAST(笔底54))
               AND  BARSLAST(笔顶54)<BARSLAST(笔底54)  
               AND (BARSNEXT(笔底54)<BARSNEXT(笔顶54) OR BARSNEXT(笔顶54)=DRAWNULL);
                  

笔底55:={分型底 AND}
                    L=LLV(L,BARSLAST(笔顶54)) AND H<HHV(H,BARSLAST(笔顶54))
               AND  BARSLAST(笔底54)<BARSLAST(笔顶54)  
               AND (BARSNEXT(笔顶54)<BARSNEXT(笔底54) OR BARSNEXT(笔底54)=DRAWNULL);

{56、合并老笔与新笔};
笔顶56:=笔顶54 OR 笔顶55;
笔底56:=笔底54 OR 笔底55;


{六、过滤笔中杂信号。}
笔顶6:=FILTERX(笔顶56 AND H=HHV(H,BARSLAST(笔底56)),BARSLAST(笔底56));
笔底6:=FILTERX(笔底56 AND L=LLV(L,BARSLAST(笔顶56)),BARSLAST(笔顶56));

{七、非笔破坏笔造成分型移位后，剔除新笔K线数量不足的情况，并过滤为画段作准备。};
笔顶7:=笔顶6 AND BARSLAST(笔底6)>3;
笔底7:=笔底6 AND BARSLAST(笔顶6)>3;

笔顶:=FILTERX(笔顶7 AND H=HHV(H,BARSLAST(笔底7)),BARSLAST(笔底7));
笔底:=FILTERX(笔底7 AND L=LLV(L,BARSLAST(笔顶7)),BARSLAST(笔顶7));


NOTEXT_上笔:DRAWLINE(笔底,L,笔顶,H,0),COLORYELLOW,LINETHICK2;
NOTEXT_下笔:DRAWLINE(笔顶,H,笔底,L,0),COLORYELLOW,LINETHICK2;

梦忠溪

好人啊！祝你股市长红！

u2_kiiue26935

无相无辩 发表于 2018-8-29 19:36
当然可以有，因为牛人太多！
转一位分笔代码：

这个分笔指标还有很多bug，指标主人的时间分型才是好东西。

无相无辩

u2_kiiue26935 发表于 2018-8-30 00:05
这个分笔指标还有很多bug，指标主人的时间分型才是好东西。

可以试着修改下啊!看看能把这笔修正到怎样程度！？